Rozdělit PDF podle záložek?

Existuje nástroj příkazového řádku napsaný v Javě s názvem Sejda, kde najdete splitbybookmarks příkaz, který dělá přesně to, co jste požadovali. Je to Java, takže běží na Linuxu a jako nástroj příkazového řádku k tomu můžete napsat skript.

Zřeknutí se odpovědnosti
Jsem jedním z autorů

máte programy, které jsou vytvořeny jako pdf-split, které to mohou udělat za vás:

A-PDF Split je velmi jednoduchý, bleskově rychlý nástroj pro stolní počítače, který vám umožní rozdělit jakýkoli soubor PDF Acrobat na menší soubory PDF. Poskytuje úplnou flexibilitu a uživatelskou kontrolu, pokud jde o to, jak jsou soubory rozděleny a jak jsou rozdělené výstupní soubory jednoznačně pojmenovány. A-PDF Split nabízí mnoho alternativ, jak jsou vaše velké soubory rozděleny – podle stránek, podle záložek a podle liché/sudé stránky. Dokonce i vy můžete extrahovat nebo odstranit část souboru PDF. A-PDF Split také nabízí pokročilé definované rozdělení, které lze uložit a později importovat pro použití s ​​opakovanými úlohami rozdělování souborů. A-PDF Split představuje maximální flexibilitu dělení souborů, aby vyhovovala všem potřebám.

A-PDF Split pracuje se soubory PDF chráněnými heslem a může na rozdělené výstupní soubory použít různé funkce zabezpečení PDF. V případě potřeby můžete znovu zkombinovat vygenerované rozdělené soubory s jinými soubory PDF pomocí nástroje, jako je A-PDF Merger, a vytvořit tak nové složené soubory PDF.

A-PDF Split NEVYŽADUJE Adobe Acrobat a vytváří dokumenty kompatibilní s Adobe Acrobat Reader verze 5 a vyšší.

upravit*

také zde našel bezplatný open source program, pokud nechcete platit.

Zde je malý program v Perlu, který pro tento úkol používám. Perl není zvláštní; je to jen obal kolem pdftk pro interpretaci jeho dump_data výstup pro přeměnu na čísla stránek pro extrakci:

#!perl
use v5.24;
use warnings;

use Data::Dumper;
use File::Path qw(make_path);
use File::Spec::Functions qw(catfile);

my $pdftk = '/usr/local/bin/pdftk';
my $file = $ARGV[0];
my $split_dir = $ENV{PDF_SPLIT_DIR} // 'pdf_splits';

die "Can't find $ARGV[0]\n" unless -e $file;

# Read the data that pdftk spits out.
open my $pdftk_fh, '-|', $pdftk, $file, 'dump_data';

my @chapters;
while( <$pdftk_fh> ) {
    state $chapter = 0;
    next unless /\ABookmark/;

    if( /\ABookmarkBegin/ ) {
        my( $title ) = <$pdftk_fh> =~ /\ABookmarkTitle:\s+(.+)/;
        my( $level ) = <$pdftk_fh> =~ /\ABookmarkLevel:\s+(.+)/;

        my( $page_number ) = <$pdftk_fh> =~ /\BookmarkPageNumber:\s+(.+)/;

        # I only want to split on chapters, so I skip higher
        # level numbers (higher means more nesting, 1 is lowest).
        next unless $level == 1;

        # If you have front matter (preface, etc) then this numbering
        # will be off. Chapter 1 might be called Chapter 3.
        push @chapters, {
            title         => $title,
            start_page    => $page_number,
            chapter       => $chapter++,
            };
        }
    }

# The end page for one chapter is one before the start page for
# the next chapter. There might be some blank pages at the end
# of the split for PDFs where the next chapter needs to start on
# an odd page.
foreach my $i ( 0 .. $#chapters - 1 ) {
    my $last_page = $chapters[$i+1]->{start_page} - 1;
    $chapters[$i]->{last_page} = $last_page;
    }
$chapters[$#chapters]->{last_page} = 'end';

make_path $split_dir;
foreach my $chapter ( @chapters ) {
    my( $start, $end ) = $chapter->@{qw(start_page last_page)};

    # slugify the title so use it as a filename
    my $title = lc( $chapter->{title} =~ s/[^a-z]+/-/gri );

    my $path = catfile( $split_dir, "$title.pdf" );
    say "Outputting $path";

    # Use pdftk to extract that part of the PDF
    system $pdftk, $file, 'cat', "$start-$end", 'output', $path;
    }

pdftk lze použít k rozdělení souboru PDF a extrahování čísel stránek záložek.

Chcete-li získat čísla stránek záložek, proveďte

pdftk in.pdf dump_data

a nechte skript číst čísla stránek z výstupu.

Poté použijte

pdftk in.pdf cat A-B output out_A-B.pdf

abyste dostali stránky z A do B do out_A-B.pdf.

Skript by mohl být něco takového:

#!/bin/bash

infile=$1 # input pdf
outputprefix=$2

[ -e "$infile" -a -n "$outputprefix" ] || exit 1 # Invalid args

pagenumbers=( $(pdftk "$infile" dump_data | \
                grep '^BookmarkPageNumber: ' | cut -f2 -d' ' | uniq)
              end )

for ((i=0; i < ${#pagenumbers[@]} - 1; ++i)); do
  a=${pagenumbers[i]} # start page number
  b=${pagenumbers[i+1]} # end page number
  [ "$b" = "end" ] || b=$[b-1]
  pdftk "$infile" cat $a-$b output "${outputprefix}"_$a-$b.pdf
done