Spuštění virtuálního linuxu pomocí qemu na Windows

Zde je návod, jak spustit minimální verzi CentOS 7 na Windows 7 Enterprise, 64 bitů, aniž bych byl členem skupiny administrátorů (neadmin).

Základní myšlenka je:

1. Stáhněte si qemu pro Windows a rozbalte jej kdekoli
2. Stáhněte si obraz ISO distribuce Linuxu, kterou chcete spustit
3. Vytvořte soubor, který bude pevným diskem vašeho virtuálního počítače
4. Spusťte qemu a zaveďte systém z obrazu CD
5. Nainstalujte operační systém
6. Restartujte virtuální počítač, tentokrát bez obrazu CD

Síť a efektní grafika je těžké nastavit. Vlastně stále bojuji...

1. Stáhněte si QEMU

Použijte předkompilovaný binární soubor, který najdete na stránce odkazů QEMU. Použil jsem k tomu verzi 2.8.0.

Chcete-li "instalovat" tuto verzi jako neadministrátor, otevřete příkazový řádek a zadejte příkaz set __COMPAT_LAYER=RunAsInvoker a spusťte qemu-w64-setup-20170131.exe z té výzvy. Instalujte do složky, kde máte oprávnění k zápisu, jako je „Moje dokumenty“ nebo něco podobného.

2. Stáhněte si ISO obraz Linuxu

Opět si pomozte. Použil jsem minimální distribuci CentOS 7, soubor se jmenuje CentOS-7-x86_64-Minimal-1611.iso .

3. Vytvořte virtuální pevný disk

Použil jsem k tomu dávkový soubor. Zkopírujte následující do souboru s názvem createvm.bat a upravte proměnné tak, aby vyhovovaly vašemu prostředí:

@echo off
rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem Safety net
rem ==================================
if not exist hda.img (
    rem CREATE a virtual hard disk 
    %QEMUDIR%\qemu-img.exe create hda.img 40G
) else (
    echo file hda.img already exist. Delete or move and try again.
    goto:eof
)

4. Spusťte QEMU, bootování z virtuálního CDa

Pro tento použijte dávku, protože ji možná používáte často. Zkopírujte následující do installvm.bat :

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"
set "ISOFILE=CentOS-7-x86_64-Minimal-1611.iso"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -cdrom %ISOFILE% -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot 

5. Nainstalujte OS

Měl jsem problém s GUI instalačním programem. Až budete vyzváni k instalaci CentOS, stiskněte TAB a nahraďte slovo quiet na konci tohoto řádku se slovem text .

Postupujte podle pokynů k instalaci na obrazovce. Po dokončení instalace se virtuální počítač ukončí. Může to chvíli trvat, zvláště když běžíte jako uživatel bez administrátora.

6. Spusťte svůj linuxový obraz v QEMU

Tento krok je to, co budete dělat znovu a znovu, abyste spustili virtuální počítač pokaždé, když ho budete potřebovat. Zkopírujte následující do runvm.bat :

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot -device e1000,netdev=user.0 -netdev user,id=user.0,hostfwd=tcp::2222-:22

Přidal jsem místní portforward:pokud ssh/putty na localhost:2222, dostanete se k SSH démonu vašeho VM. Pozor, firewalld nebo iptables možná blokovat provoz v závislosti na způsobu instalace Linuxu.

Manuál Qemu by byl dobrým místem, kde začít. Pomůže vám to zjistit, co byste měli dělat dál, což je říct qemu, co má dělat a jak přesně to udělat.